· Дата 2009-10-13 ·

Записи на дату «2009-10-13»

READ-ONLY ветки в SVN

2009-10-13 06:16:21

@echo off
rem Pre-commit hook, checking READ-ONLY status of branch in SVN
rem Author: Andrey Pohilko apc@apc.kg

set PROPNAME=fininfor:readonly

rem Here's loop by changes in commit, but we'll take only first
for /F "tokens=1,2" %%B in ('svnlook changed %1 -t %2') do (
	rem echo Change: %%B %%C

	rem If the change is propchange then it's ok
	rem Because we need a way to remove restricting property
	if "%%B"=="_U" exit /B 0

	rem Parse first 3 path components
	for /F "tokens=1,2,3 delims=/" %%D in ("%%C") do (
		rem echo Path components %%D %%E %%F

		rem first check - 3rd level dir
		for /F %%P in ('svnlook propget %1 %PROPNAME% /%%D/%%E/%%F') do (
			rem echo Property value: %%P
			if not ""=="%%P" (
				echo Commits to read-only branch are restricted: %%P 1>&2
				exit 1
			)
		)


		rem second check - 2nd level dir
		for /F %%P in ('svnlook propget %1 %PROPNAME% /%%D/%%E') do (
			rem echo Property value: %%P
			if not ""=="%%P" (
				echo Commits to read-only branch are restricted: %%P 1>&2
				exit 1
			)
		)


		rem last check - 1st level dir
		for /F %%P in ('svnlook propget %1 %PROPNAME% /%%D') do (
			rem echo Property value: %%P
			if not ""=="%%P" (
				echo Commits to read-only branch are restricted: %%P 1>&2
				exit 1
			)
		)
	)

	rem First change path is enough, exiting with success
	exit /B 0
)

Комментариев: 0 | Добавить комментарий